ools-benchmark.7.16.0.Final.source-code.fireAlarmMvel.drl Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of drools-benchmark Show documentation

Drools Benchmark

There is a newer version: 7.36.1.Final

/*
 * Copyright 2015 Red Hat, Inc. and/or its affiliates.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * 
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
*/

dialect "mvel"

import java.util.*
import org.drools.benchmark.model.*

rule "When there is a fire turn on the sprinkler"
when
    Fire($roomA_ : room)
    $sprinklerA_ : Sprinkler( room == $roomA_, on == false )
then
    modify( $sprinklerA_ ) { setOn( true ) };
//    System.out.println( "Turn on the sprinkler for room " + $roomA_.getName() );
end

rule "When the fire is gone turn off the sprinkler"
when
    $roomB_ : Room( )
    $sprinklerB_ : Sprinkler( room == $roomB_, on == true )
    not Fire( room == $roomB_ )
then
    modify( $sprinklerB_ ) { setOn( false ) };
//    System.out.println( "Turn off the sprinkler for room " + $roomB_.getName() );
end

rule "Raise the alarm when we have one or more fires"
when
    exists Fire()
then
    insert( new Alarm() );
//    System.out.println( "Raise the alarm" );
end

rule "Cancel the alarm when all the fires have gone"
when
    not Fire()
    $alarm_ : Alarm()
then
    retract( $alarm_ );
//    System.out.println( "Cancel the alarm" );
end

rule "Status output when things are ok"
when
    not Alarm()
    not Sprinkler( on == true )
then
//    System.out.println( "Everything is ok" );
end