org.gradle.tooling.model.internal.ImmutableDomainObjectSetTest.groovy Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of gradle-api Show documentation

Gradle 6.9.1 API redistribution.

There is a newer version: 8.11.1

/*
 * Copyright 2011 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.gradle.tooling.model.internal

import spock.lang.Specification

class ImmutableDomainObjectSetTest extends Specification {

    def emptySetHasZeroSize() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet([])

        expect:
        set.size() == 0
        set.isEmpty()
    }

    def canQuerySize() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet(['a', 'b', 'c'])

        expect:
        set.size() == 3
        !set.isEmpty()
    }

    def canGetElementByIndex() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet(['a', 'b', 'c'])

        expect:
        set[0] == 'a'
        set[2] == 'c'
    }

    def throwsIndexOutOfBoundsExceptionForInvalidIndex() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet(['a', 'b', 'c'])

        when:
        set[4]

        then:
        IndexOutOfBoundsException e = thrown()

        when:
        set[-1]

        then:
        e = thrown()
    }

    def iteratorOfEmptySetHasNoElements() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet([])

        expect:
        !set.iterator().hasNext()
    }

    def iteratorMaintainsOrderOfOriginalCollection() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet(['a', 'b', 'c'])

        expect:
        set.collect { it } == ['a', 'b', 'c']
        set.iterator().collect { it } == ['a', 'b', 'c']
    }

    def canGetElementsAsAList() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet(['a', 'b', 'c'])

        expect:
        set.all == ['a', 'b', 'c']
    }

    def ignoresDuplicateElementsInOriginalCollection() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet(['a', 'b', 'a', 'b', 'c'])

        expect:
        set.size() == 3
        set.collect { it } == ['a', 'b', 'c']
    }

    def cannotAddElementsToSet() {
        ImmutableDomainObjectSet set = new ImmutableDomainObjectSet([])

        when:
        set.add('a')

        then:
        UnsupportedOperationException e = thrown()
    }
}