org.codenarc.rule.basic.ConstantTernaryExpressionRule.groovy Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of CodeNarc Show documentation

The CodeNarc project provides a static analysis tool for Groovy code.

There is a newer version: 3.5.0-groovy-4.0

/*
 * Copyright 2010 the original author or authors.
 * 
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 * 
 *      http://www.apache.org/licenses/LICENSE-2.0
 * 
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.codenarc.rule.basic

import org.codehaus.groovy.ast.expr.TernaryExpression
import org.codenarc.rule.AbstractAstVisitor
import org.codenarc.rule.AbstractAstVisitorRule
import org.codenarc.util.AstUtil

/**
 * Rule that checks for ternary expressions with a constant value for the boolean expression, such as:
 * 
 *   true ? x : y
 *   false ? x : y
 *   Boolean.TRUE ? x : y
 *   Boolean.FALSE ? x : y
 *   null ? x : y
 *   0 ? x : y
 *   99.7 ? x : y
 *   "" ? x : y
 *   "abc" ? x : y
 *   [:] ? x : y
 *   [a:123, b:456] ? x : y
 *   [a, b, c] ? x : y
 * 
 *
 * Also checks for the same types of constant values for the boolean expressions within the "short"
 * ternary expressions, also known as the "Elvis" operator, e.g.:
 * 
 *   true ?: y
 *   null ?: y
 *   99.7 ?: y
 *   "abc" ?: y
 *   [a:123] ?: y
 * 
 *
 * @author Chris Mair
 */
class ConstantTernaryExpressionRule extends AbstractAstVisitorRule {
    String name = 'ConstantTernaryExpression'
    int priority = 2
    Class astVisitorClass = ConstantTernaryExpressionAstVisitor
}

class ConstantTernaryExpressionAstVisitor extends AbstractAstVisitor  {

    void visitTernaryExpression(TernaryExpression ternaryExpression) {
        if (isFirstVisit(ternaryExpression)) {
            def booleanExpression = ternaryExpression.booleanExpression
            if (AstUtil.isConstantOrLiteral(booleanExpression.expression)) {
                addViolation(ternaryExpression, "The ternary expression contains the constant $booleanExpression.expression")
            }
        }
        super.visitTernaryExpression(ternaryExpression)
    }

}