org.codenarc.rule.unnecessary.UnnecessaryBooleanExpressionRule.groovy Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of CodeNarc Show documentation

The CodeNarc project provides a static analysis tool for Groovy code.

There is a newer version: 3.5.0-groovy-4.0

/*
 * Copyright 2010 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.codenarc.rule.unnecessary

import org.codehaus.groovy.ast.expr.BinaryExpression
import org.codehaus.groovy.ast.expr.NotExpression
import org.codenarc.rule.AbstractAstVisitor
import org.codenarc.rule.AbstractAstVisitorRule
import org.codenarc.util.AstUtil

/**
 * Rule that checks unnecessary boolean expressions, including ANDing (&&) or ORing (||) with
 * true, false, null, or a Map/List/String/Number literal.
 *
 * This rule also checks for negation (!) of true, false,
 * null, or a Map/List/String/Number literal.
 * Examples include:
 * 
 *   def result = value && true
 *   if (false || value) { .. }
 *   return value && Boolean.FALSE
 *   result = value && "abc"
 *   result = null && value
 *   result = value && 123
 *   result = 678.123 || true
 *   result = value && [x, y]
 *   def result = [a:123] && value
 *
 *   result = !true
 *   result = !false
 *   result = !Boolean.TRUE
 *   result = !null
 *   result = !"abc"
 *   result = ![a:123]
 *   result = ![a,b]
 * 
 *
 * @author Chris Mair
  */
class UnnecessaryBooleanExpressionRule extends AbstractAstVisitorRule {
    String name = 'UnnecessaryBooleanExpression'
    int priority = 3
    Class astVisitorClass = UnnecessaryBooleanExpressionAstVisitor
}

class UnnecessaryBooleanExpressionAstVisitor extends AbstractAstVisitor  {

    private static final List BOOLEAN_LOGIC_OPERATIONS = ['&&', '||']

    @Override
    void visitBinaryExpression(BinaryExpression expression) {
        def operationName = expression.operation.text
        if (operationName in BOOLEAN_LOGIC_OPERATIONS &&
                (AstUtil.isConstantOrLiteral(expression.rightExpression) ||
                 AstUtil.isConstantOrLiteral(expression.leftExpression))) {
            addViolation(expression, "The expression using $operationName is compared to a constant")
        }
        super.visitBinaryExpression(expression)
    }

    @Override
    void visitNotExpression(NotExpression expression) {
        if (AstUtil.isConstantOrLiteral(expression.expression)) {
            addViolation(expression, 'The Not expression contains a literal or constant. ')
        }
        super.visitNotExpression(expression)
    }

}