org.codenarc.rule.basic.ConstantIfExpressionRule.groovy Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of CodeNarc Show documentation

The CodeNarc project provides a static analysis tool for Groovy code.

There is a newer version: 3.5.0-groovy-4.0

/*
 * Copyright 2010 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.codenarc.rule.basic

import org.codehaus.groovy.ast.stmt.IfStatement
import org.codenarc.rule.AbstractAstVisitor
import org.codenarc.rule.AbstractAstVisitorRule
import org.codenarc.util.AstUtil

/**
 * Rule that checks for if statement with a constant value for the if expression, such as:
 * 
 *   if (true) { .. }
 *   if (false) { .. }
 *   if (Boolean.TRUE) { .. }
 *   if (Boolean.FALSE) { .. }
 *   if (null) { .. }
 *   if (0) { .. }
 *   if (99.7) { .. }
 *   if ("") { .. }
 *   if ("abc") { .. }
 *   if ([a:123, b:456]) { .. }
 *   if ([a, b]) { .. }
 * 
 *
 * @author Chris Mair
 */
class ConstantIfExpressionRule extends AbstractAstVisitorRule {
    String name = 'ConstantIfExpression'
    int priority = 2
    Class astVisitorClass = ConstantIfExpressionAstVisitor
}

class ConstantIfExpressionAstVisitor extends AbstractAstVisitor  {

    @Override
    void visitIfElse(IfStatement ifStatement) {
        if (isFirstVisit(ifStatement)) {
            def booleanExpression = ifStatement.booleanExpression
            if (AstUtil.isConstantOrLiteral(booleanExpression.expression)) {
                addViolation(ifStatement, "The if statement condition ($booleanExpression.text) contains a constant")
            }
        }
        super.visitIfElse(ifStatement)
    }

}