org.grails.cli.gradle.GradleInvoker.groovy Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of grace-shell Show documentation

Grace Framework : Grace Shell

There is a newer version: 2023.1.0-RC1

/*
 * Copyright 2014-2022 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.grails.cli.gradle

import groovy.transform.CompileStatic
import org.gradle.tooling.BuildLauncher

import grails.util.Environment

import org.grails.build.parsing.CommandLine
import org.grails.cli.profile.ExecutionContext

/**
 * Allow dynamic invocation of Gradle tasks
 *
 * @author Graeme Rocher
 * @since 3.0
 */
@CompileStatic
class GradleInvoker {

    ExecutionContext executionContext

    GradleInvoker(ExecutionContext executionContext) {
        this.executionContext = executionContext
    }

    @Override
    Object invokeMethod(String name, Object args) {
        Object[] argArray = (Object[]) args

        GradleUtil.runBuildWithConsoleOutput(executionContext) { BuildLauncher buildLauncher ->
            buildLauncher.forTasks(name.split(' '))
            List arguments = []
            arguments << "-Dgrails.env=${Environment.current.name}".toString()

            def commandLine = executionContext.commandLine
            if (commandLine.hasOption(CommandLine.STACKTRACE_ARGUMENT)) {
                arguments << '--stacktrace'
                arguments << '-Dgrails.full.stacktrace=true'
            }

            arguments.addAll(argArray*.toString() as String[])
            buildLauncher.withArguments(arguments as String[])
        }
    }

    GradleAsyncInvoker getAsync() {
        new GradleAsyncInvoker(this)
    }

}