report_queries.missing_label.rq Maven / Gradle / Ivy

Go to download

Show more of this group Show more artifacts with this name
Show all versions of robot-core Show documentation

Core library for ROBOT: Library for working with OWL ontologies, especially Open Biological and Biomedical Ontologes (OBO).

The newest version!

# # Missing Label
#
# **Problem:** An entity does not have a label or the label is empty. This may cause confusion or misuse. Excludes deprecated entities.
#
# **OBO Foundry Principle:** [12 - Naming Conventions](http://www.obofoundry.org/principles/fp-012-naming-conventions.html)
#
# **Solution:** Add a label, or make it non-empty.

PREFIX owl: 
PREFIX rdf: 
PREFIX rdfs: 
PREFIX oboInOwl: 

SELECT DISTINCT ?entity ?property ?value WHERE {
  VALUES ?property { rdfs:label }
  ?entity ?any ?o .
  FILTER NOT EXISTS {
     ?entity ?property ?value .
     FILTER(str(?value) != "")
  }
  FILTER NOT EXISTS { ?entity a owl:Ontology }
  FILTER NOT EXISTS { ?entity owl:deprecated true }
  FILTER NOT EXISTS {
    ?entity rdfs:subPropertyOf oboInOwl:SubsetProperty .
  }
  FILTER EXISTS {
    ?entity ?prop2 ?object .
    FILTER (?prop2 != rdf:type)
    FILTER (?prop2 != owl:equivalentClass)
    FILTER (?prop2 != owl:disjointWith)
    FILTER (?prop2 != owl:equivalentProperty)
    FILTER (?prop2 != owl:sameAs)
    FILTER (?prop2 != owl:differentFrom)
    FILTER (?prop2 != owl:inverseOf)
  }
  FILTER (!isBlank(?entity))
}
ORDER BY ?entity